\lambda\delta home page: Open Symbolic Notation

Open Symbolic Notation

$\lambda\delta rainbow rule$

Open Symbolic Notation, abbreviated OSN, is an easy and flexible data-interchange text format intended for the lightweight representation of generic abstract syntax trees in the domain of formal languages. In order to meet these design goals, OSN pursues the following features.

Symbolic expressions based on widely accepted syntactical conventions provide for a lightweight and generic grammar, which is both easy for machines to process, and easy for humans to understand. As a mean to support efficient information processing, OSN aims at an economic representation of data contrary to XML design goal 10. Compared to other data-interchange formats based on symbolic expressions, like canonical symbolic expressions, representing arbitrary data in binary format is a secondary concern in the design of OSN, as well as the support for canonicalization. Apparently, these features fall outside the scope of OSN, which targets the data structures of formal languages.

Optionally qualified symbolic expressions allow OSN texts to mix data from different domains preserving their own semantics because name conflicts can be avoided. As a consequence OSN documents are easy to extend in that domain-specific OSN applications can work as expected even if data from different domains is added to the text they process.

The US-ASCII character set, extended to UTF-8 in free-form text strings for the convenience of human readers, makes OSN documents easy to visualize and transport over communication media. OSN design aims at supporting application-independent standard encodings.

Grammar $\lambda\delta butterfly$

An OSN text uses the UTF-8 character set and contains the next seven tokens that we define in a very common EBNF variant. Characters not starting a token are not allowed. The ones in the range U+0021 ... U+007E are ! # $ % & * / ? @ \ ^ | ~ and are available for extensions of OSN.

This token can represent the identifiers and the numerical constants of most programming languages:
symbol = 1 * symbol-char ;
symbol-char = '+' | '-' | '.' | '0' | ... | '9' | 'A' | ... | 'Z' | '_' | '`' | 'a' | ... | 'z' ;

This token contains free-form text with commonly accepted escape sequences:
string = '"' , * ( string-char | "'" | '\' escape ) , '"' ;
string-char = ( #0 | ... | #10FFFF ) - ( #0 | ... | #1F | "'" | '\' | '"' | #7F ) ;
escape = 1 * space | '"' | "'" | '(' | ')' | '0' | '\' | 'a' | 'b' | 'e' | 'f' | 'n' | 'r' | 't' | ( 'u' , 4 * 4 hex ) | 'v' | ( 'x' , 2 * 2 hex ) ;
space = #9 | ... | #D | #20 ;
hex = '0' | ... | '9' | 'A' | ... | 'F' | 'a' | ... | 'f' ;

This token is a widely used alternative of the former token:
string-alt = "'" , * ( string-char | '"' | '\' escape ) , "'" ;

This token separates the qualifiers of a symbolic expression:
sep = ':' ;

This token starts a compound symbolic expression:
open = '(' | '<' | '[' | '{' ;

This token ends a compound symbolic expression:
close = ')' | '>' | ']' | '}' ;

This token is ignored and separates the other tokens:
gap = space | ',' | ';' | '=' ;

The grammar of OSN is very liberal by design. Spaces of the form 1 * gap can appear between any pair of tokens.

An OSN text:
text = * q-expr ;

A qualified symbolic expression:
q-expr = * ( symbol , 1 * sep ) , expr ;

An unqualified symbolic expression:
expr = symbol | string | string-alt | ( open , text , close ) ;

Semantics $\lambda\delta butterfly$

Forthcoming ...

Implementation $\lambda\delta butterfly$

Forthcoming ...

$\lambda\delta rainbow rule$

Last update: Tue, 22 Dec 2020 18:19:03 +0100